# Importance of variables investigation

## Introduction

This blog post demonstrates a procedure for variable importance investigation of mixed categorical and numerical data.

The procedure was used in a previous blog “Classification and association rules for census income data”, . It is implemented in the package VariableImportanceByClassifiers.m, , and described below; I took it from .

The document “Importance of variables investigation guide”, , has much more extensive descriptions, explanations, and code for importance of variables investigation using classifiers, Mosaic plots, Decision trees, Association rules, and Dimension reduction.

At community.wolfram.com I published the discussion opening of “Classifier agnostic procedure for finding the importance of variables” that has an exposition that parallels this blog post, but uses a different data set (“Mushroom”). (The discussion was/is also featured in “Staff picks”; it is easier to follow the Mathematica code in it.)

## Procedure outline

Here we describe the procedure used (that is also done in ).

1. Split the data into training and testing datasets.

2. Build a classifier with the training set.

3. Verify using the test set that good classification results are obtained. Find the baseline accuracy.

4. If the number of variables (attributes) is k for each i, 1ik:

4.1. Shuffle the values of the i-th column of the test data and find the classification success rates.

5. Compare the obtained k classification success rates between each other and with the success rates obtained by the un-shuffled test data.

The variables for which the classification success rates are the worst are the most decisive.

Note that instead of using the overall baseline accuracy we can make the comparison over the accuracies for selected, more important class labels. (See the examples below.)

The procedure is classifier agnostic. With certain classifiers, Naive Bayesian classifiers and Decision trees, the importance of variables can be directly concluded from their structure obtained after training.

The procedure can be enhanced by using dimension reduction before building the classifiers. (See  for an outline.)

## Implementation description

The implementation of the procedure is straightforward in Mathematica — see the package VariableImportanceByClassifiers.m, .

The package can be imported with the command:

`Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/VariableImportanceByClassifiers.m"]`

At this point the package has only one function, AccuracyByVariableShuffling, that takes as arguments a ClassifierFunction object, a dataset, optional variable names, and the option “FScoreLabels” that allows the use of accuracies over a custom list of class labels instead of overall baseline accuracy.

Here is the function signature:

`AccuracyByVariableShuffling[ clFunc_ClassifierFunction, testData_, variableNames_:Automatic, opts:OptionsPattern[] ]`

The returned result is an Association structure that contains the baseline accuracy and the accuracies corresponding to the shuffled versions of the dataset. I.e. steps 3 and 4 of the procedure are performed by AccuracyByVariableShuffling. Returning the result in the form Association[___] means we can treat the result as a list with named elements similar to the list structures in Lua and R.

For the examples in the next section we also going to use the package MosaicPlot.m, , that can be imported with the following command:

`Import["https://raw.githubusercontent.com/antononcube/MathematicaForPrediction/master/MosaicPlot.m"]`

## Concrete application over the “Titanic” dataset

1. Load some data.

```testSetName = "Titanic"; trainingSet = ExampleData[{"MachineLearning", testSetName}, "TrainingData"]; testSet = ExampleData[{"MachineLearning", testSetName}, "TestData"];```

2. Variable names and unique class labels.

```varNames = Flatten[List @@ ExampleData[{"MachineLearning", testSetName}, "VariableDescriptions"]]```

`(*Out= {"passenger class", "passenger age", "passenger sex", "passenger survival"} *)`

```classLabels = Union[ExampleData[{"MachineLearning", testSetName}, "Data"][[All, -1]]]```

`(*Out= {"died", "survived"} *)`

3. Here is a data summary.

```Grid[List@RecordsSummary[(Flatten /@ (List @@@ Join[trainingSet, testSet])) /. _Missing -> 0, varNames], Dividers -> All, Alignment -> {Left, Top}]``` 4. Make the classifier.

`clFunc = Classify[trainingSet, Method -> "RandomForest"]`

`(*Out= ClassifierFunction[\[Ellipsis]] *)`

5. Obtain accuracies after shuffling.

`accs = AccuracyByVariableShuffling[clFunc, testSet, varNames]`

```(*Out= <|None -> 0.78117, "passenger class" -> 0.704835, "passenger age" -> 0.768448, "passenger sex" -> 0.610687|>*)```

6. Tabulate the results.

```Grid[ Prepend[ List @@@ Normal[accs/First[accs]], Style[#, Bold, Blue, FontFamily -> "Times"] & /@ {"shuffled variable", "accuracy ratio"}], Alignment -> Left, Dividers -> All]``` 7. Further confirmation of the found variable importance can be done using the mosaic plots.
We can see that female passengers are much more likely to survive and especially female passengers from first and second class.

```t = (Flatten /@ (List @@@ trainingSet)); MosaicPlot[t[[All, {1, 3, 4}]], ColorRules -> {3 -> ColorData[7, "ColorList"]} ]``` 5a. In order to use F-scores instead of overall accuracy the desired class labels are specified with the option “FScoreLabels”.

```accs = AccuracyByVariableShuffling[clFunc, testSet, varNames, "FScoreLabels" -> classLabels]```

```(*Out= <| None -> {0.838346, 0.661417}, "passenger class" -> {0.79927, 0.537815}, "passenger age" -> {0.828996, 0.629032}, "passenger sex" -> {0.703499, 0.337449}|>*)```

5b. Here is another example that uses the class label with the smallest F-score.
(Probably the most important since it is most mis-classified).

```accs = AccuracyByVariableShuffling[clFunc, testSet, varNames, "FScoreLabels" -> Position[#, Min[#]][[1, 1, 1]] &@ ClassifierMeasurements[clFunc, testSet, "FScore"]]```

```(*Out= {0.661417}, "passenger class" -> {0.520325}, "passenger age" -> {0.623482}, "passenger sex" -> {0.367521}|>*)```

5c. It is good idea to verify that we get the same results using different classifiers. Below is given code that computes the shuffled accuracies and returns the relative damage scores for a set of methods of Classify.

```mres = Association@Map[ Function[{clMethod}, cf = Classify[titanicTrainingData, Method -> clMethod]; accRes = AccuracyByVariableShuffling[cf, testSet, varNames, "FScoreLabels" -> "survived"]; clMethod -> (accRes[None] - Rest[accRes])/accRes[None] ], {"LogisticRegression", "NearestNeighbors", "NeuralNetwork", "RandomForest", "SupportVectorMachine"}] ; Dataset[mres]``` ## References

 Anton Antonov, “Classification and association rules for census income data”, (2014), MathematicaForPrediction at WordPress.com.

 Anton Antonov, Variable importance determination by classifiers implementation in Mathematica, (2015), source code at MathematicaForPrediction at GitHub, package VariableImportanceByClassifiers.m.

 Anton Antonov, “Importance of variables investigation guide”, (2016), MathematicaForPrediction at GitHub, folder Documentation.

 Anton Antonov, Mosaic plot for data visualization implementation in Mathematica, (2014), MathematicaForPrediction at GitHub, package MosaicPlot.m.

 Leo Breiman et al., Classification and regression trees, Chapman & Hall, 1984, ISBN-13: 978-0412048418.